Java

本类阅读TOP10

·使用MyEclipse开发Struts框架的Hello World!(录像1)
·hibernate配置笔记
·AOP编程入门--Java篇
·linux下Tomcat 5.0.20 与 Apache 2 安装/集成/配置
·在win2003下整合了整合Tomcat5.5+ apache_2.0.53+ mod_jk_2.0.47.dll
·构建Linux下IDE环境--Eclipse篇
·Jsp 连接 mySQL、Oracle 数据库备忘(Windows平台)
·ASP、JSP、PHP 三种技术比较
·Tomcat5.5.9的安装配置
·AWT GUI 设计笔记(二)

→ 分类导航

VC语言	Delphi
VB语言	ASP
Perl	Java
Script	数据库
其他语言	游戏开发
文件格式	网站制作
软件工程	.NET开发

Mini Java编译器（二）——语法（BNF）

作者：未知来源：月光软件站 加入时间：2005-2-28　月光软件站

二、Mini Java的文法

BNF

Goal	::=	MainClass ( TypeDeclaration )* <EOF>
MainClass	::=	"class" Identifier "{" "public" "static" "void" "main" "(" "String" "[" "]" Identifier ")" "{" PrintStatement "}" "}"
TypeDeclaration	::=	ClassDeclaration
	\|	ClassExtendsDeclaration
ClassDeclaration	::=	"class" Identifier "{" ( VarDeclaration )* ( MethodDeclaration )* "}"
ClassExtendsDeclaration	::=	"class" Identifier "extends" Identifier "{" ( VarDeclaration )* ( MethodDeclaration )* "}"
VarDeclaration	::=	Type Identifier ";"
MethodDeclaration	::=	"public" Type Identifier "(" ( FormalParameterList )? ")" "{" ( VarDeclaration )* ( Statement )* "return" Expression ";" "}"
FormalParameterList	::=	FormalParameter ( FormalParameterRest )*
FormalParameter	::=	Type Identifier
FormalParameterRest	::=	"," FormalParameter
Type	::=	ArrayType
	\|	BooleanType
	\|	IntegerType
	\|	Identifier
ArrayType	::=	"int" "[" "]"
BooleanType	::=	"boolean"
IntegerType	::=	"int"
Statement	::=	Block
	\|	AssignmentStatement
	\|	ArrayAssignmentStatement
	\|	IfStatement
	\|	WhileStatement
	\|	PrintStatement
Block	::=	"{" ( Statement )* "}"
AssignmentStatement	::=	Identifier "=" Expression ";"
ArrayAssignmentStatement	::=	Identifier "[" Expression "]" "=" Expression ";"
IfStatement	::=	"if" "(" Expression ")" Statement "else" Statement
WhileStatement	::=	"while" "(" Expression ")" Statement
PrintStatement	::=	"System.out.println" "(" Expression ")" ";"
Expression	::=	AndExpression
	\|	CompareExpression
	\|	PlusExpression
	\|	MinusExpression
	\|	TimesExpression
	\|	ArrayLookup
	\|	ArrayLength
	\|	MessageSend
	\|	PrimaryExpression
AndExpression	::=	PrimaryExpression "&&" PrimaryExpression
CompareExpression	::=	PrimaryExpression "<" PrimaryExpression
PlusExpression	::=	PrimaryExpression "+" PrimaryExpression
MinusExpression	::=	PrimaryExpression "-" PrimaryExpression
TimesExpression	::=	PrimaryExpression "*" PrimaryExpression
ArrayLookup	::=	PrimaryExpression "[" PrimaryExpression "]"
ArrayLength	::=	PrimaryExpression "." "length"
MessageSend	::=	PrimaryExpression "." Identifier "(" ( ExpressionList )? ")"
ExpressionList	::=	Expression ( ExpressionRest )*
ExpressionRest	::=	"," Expression
PrimaryExpression	::=	IntegerLiteral
	\|	TrueLiteral
	\|	FalseLiteral
	\|	Identifier
	\|	ThisExpression
	\|	ArrayAllocationExpression
	\|	AllocationExpression
	\|	NotExpression
	\|	BracketExpression
IntegerLiteral	::=	<INTEGER_LITERAL>
TrueLiteral	::=	"true"
FalseLiteral	::=	"false"
Identifier	::=	<IDENTIFIER>
ThisExpression	::=	"this"
ArrayAllocationExpression	::=	"new" "int" "[" Expression "]"
AllocationExpression	::=	"new" Identifier "(" ")"
NotExpression	::=	"!" Expression
BracketExpression	::=	"(" Expression ")"

（待续）

相关文章：

相关软件：